Equipads - John Dunn, Consultant, Ambertec, P.E., P.C.

Imagine having to attenuate a fairly high power signal, high enough in power that one single attenuator pad can't handle the power dissipation requirement. We can use a cascade of attenuators, but we want to spread the burden, so to speak, so that each attenuator in the cascade will dissipate an equal share of the total power dissipation.

The following derivation shows how to calculate the dB values for this: 

 
Of course, the fact that this sketch shows only six attenuator pads is merely an artifice of convenience. There is really no limit to how many the cascade can contain, but this sketch and the GWBASIC code below just happen to be limited to that number.

This program first presents three examples of 3 dB in two pads, 10 dB in four pads and 20 dB in six pads, presents the dB attenuation values of each pad and the fraction of the input power that each pad will absorb. Then it asks how many dB of total attenuation you require and in how many pads.

 

The inquiries to you the user are in an endless loop, so use Ctrl-Break to exit the program.

 

10 CLS:SCREEN 9:COLOR 15,1:DIM A(10),P(10),A$(10),B$(10),PL(10)

20 PRINT "save "+CHR$(34)+"equipads.bas"+CHR$(34):PRINT

30 PRINT "save "+CHR$(34)+"a:equipads.bas"+CHR$(34):PRINT:PRINT

40 A$(1)="##.## dB = ##.## dB + ##.## dB":B$(1)="            #.###   + #.###   "

50 FOR J=2 TO 5:A$(J)=A$(J-1)+" + ##.## dB":B$(J)=B$(J-1)+" + #.###   ":NEXT J

60 C$="Examples of equal power pads and their fractions "

70 C$=C$+"of input power absorbed:":PRINT C$:PRINT:ON ERROR GOTO 240

80 READ ADB,N:GOSUB 90:GOTO 80:DATA 3,2,10,4,20,6

90 ASUM=0:FOR J=1 TO 10:A(J)=0:NEXT J

100 FOR J=1 TO N:NUM=(N+1-J)*10^(ADB/10)+(J-1):DEN=(N-J)*10^(ADB/10)+J

110 A(J)=10*LOG(NUM/DEN):A(J)=A(J)/2.30259:ASUM=ASUM+A(J):NEXT J:P(0)=1

120 FOR J=1 TO N:P(J)=P(J-1)/(10^(A(J)/10)):PL(J)=P(J-1)-P(J):NEXT J

130 IF N=2 THEN PRINT USING A$(1);ASUM,A(1),A(2)

140 IF N=2 THEN PRINT USING B$(1);PL(1),PL(2)

150 IF N=3 THEN PRINT USING A$(2);ASUM,A(1),A(2),A(3)

160 IF N=3 THEN PRINT USING B$(2);PL(1),PL(2),PL(3)

170 IF N=4 THEN PRINT USING A$(3);ASUM,A(1),A(2),A(3),A(4)

180 IF N=4 THEN PRINT USING B$(3);PL(1),PL(2),PL(3),PL(4)

190 IF N=5 THEN PRINT USING A$(4);ASUM,A(1),A(2),A(3),A(4),A(5)

200 IF N=5 THEN PRINT USING B$(4);PL(1),PL(2),PL(3),PL(4),PL(5)

210 IF N=6 THEN PRINT USING A$(5);ASUM,A(1),A(2),A(3),A(4),A(5),A(6)

220 IF N=6 THEN PRINT USING B$(5);PL(1),PL(2),PL(3),PL(4),PL(5),PL(6)

230 RETURN

240 PRINT:INPUT "How many dB and with how many pads ";ADB,N:IF N>6 THEN N=6

250 GOSUB 90:GOTO 240

Comments

[plumbing supplies]

In any system, the amount of power at the beginning is usually less than at the end. This is called power dissipation. According to the laws of thermodynamics, energy cannot be created or destroyed, only changed or transferred. Power loss in most systems is caused by transference from its initial medium into heat. The overall power loss to a system can be tested and calculated using the laws of thermodynamics and some equipment.